Les traductions sont fournies par des outils de traduction automatique. En cas de conflit entre le contenu d'une traduction et celui de la version originale en anglais, la version anglaise prévaudra.
# Utilisation de SSIS
Après avoir déployé le projet SSIS dans le catalogue SSIS, vous pouvez exécuter des packages directement à partir de SSMS ou les planifier à l'aide de SQL Server Agent. Vous devez utiliser une connexion authentifiée par Windows pour exécuter les packages SSIS. Pour plus d'informations, consultez [Configuration d'un utilisateur authentifié par Windows pour SSIS](SSIS.Permissions.md#SSIS.Use.Auth).
**Topics**
+ [Définition des gestionnaires de connexion à la base de données pour les projets SSIS](#SSIS.Use.ConnMgrs)
+ [Création d'un proxy SSIS](#SSIS.Use.Proxy)
+ [Planification d'un package SSIS à l'aide de SQL Server Agent](#SSIS.Use.Schedule)
+ [Révocation de l'accès SSIS à partir du proxy](#SSIS.Use.Revoke)
## Définition des gestionnaires de connexion à la base de données pour les projets SSIS
Lorsque vous utilisez un gestionnaire de connexions, vous pouvez employer les types d'authentification suivants :
+ Pour les connexions aux bases de données locales à l'aide d'AWS Managed Active Directory, vous pouvez utiliser l'authentification SQL ou l'authentification Windows. Pour l'authentification Windows, utilisez `DB_instance_name.fully_qualified_domain_name` comme nom de serveur de la chaîne de connexion.
`myssisinstance.corp-ad.example.com` en est un exemple, où `myssisinstance` est le nom de l'instance de base de données et `corp-ad.example.com` le nom de domaine entièrement qualifié.
+ Pour les connexions distantes, utilisez toujours l'authentification SQL.
+ Pour les connexions aux bases de données locales à l'aide d'Active Directory autogéré, vous pouvez utiliser l'authentification SQL ou l'authentification Windows. Pour l'authentification Windows, utilisez `.` ou `LocalHost` comme nom de serveur de la chaîne de connexion.
## Création d'un proxy SSIS
Pour pouvoir planifier des packages SSIS à l'aide de SQL Server Agent, créez des informations d'identification SSIS et un proxy SSIS. Exécutez ces procédures en tant qu'utilisateur authentifié par Windows.
**Pour créer les informations d'identification SSIS**
+ Créez les informations d'identification pour le proxy. Pour ce faire, vous pouvez utiliser SSMS ou l'instruction SQL suivante.
```
USE [master]
GO
CREATE CREDENTIAL [SSIS_Credential] WITH IDENTITY = N'mydomain\user_name', SECRET = N'mysecret'
GO
```
**Note**
`IDENTITY` doit être une connexion authentifiée par domaine. Remplacez `mysecret` par le mot de passe de la connexion authentifiée par le domaine.
Chaque fois que l'hôte principal SSISDB est modifié, modifiez les informations d'identification du proxy SSIS pour permettre au nouvel hôte d'y accéder.
**Pour créer le proxy SSIS**
1. Utilisez l'instruction SQL suivante pour créer le proxy.
```
USE [msdb]
GO
EXEC msdb.dbo.sp_add_proxy @proxy_name=N'SSIS_Proxy',@credential_name=N'SSIS_Credential',@description=N''
GO
```
1. Utilisez l'instruction SQL suivante pour accorder l'accès au proxy à d'autres utilisateurs.
```
USE [msdb]
GO
EXEC msdb.dbo.sp_grant_login_to_proxy @proxy_name=N'SSIS_Proxy',@login_name=N'mydomain\user_name'
GO
```
1. Utilisez l'instruction SQL suivante pour donner au sous-système SSIS accès au proxy.
```
USE [msdb]
GO
EXEC msdb.dbo.rds_sqlagent_proxy @task_type='GRANT_SUBSYSTEM_ACCESS',@proxy_name='SSIS_Proxy',@proxy_subsystem='SSIS'
GO
```
**Pour afficher le proxy et les octrois sur le proxy**
1. Utilisez l'instruction SQL suivante pour afficher les bénéficiaires du proxy.
```
USE [msdb]
GO
EXEC sp_help_proxy
GO
```
1. Utilisez l'instruction SQL suivante pour afficher les octrois du sous-système.
```
USE [msdb]
GO
EXEC msdb.dbo.sp_enum_proxy_for_subsystem
GO
```
## Planification d'un package SSIS à l'aide de SQL Server Agent
Après avoir créé les informations d'identification et le proxy et accordé l'accès SSIS au proxy, vous pouvez créer un tâche SQL Server Agent pour planifier le package SSIS.
**Pour planifier le package SSIS**
+ Vous pouvez utiliser SSMS ou T-SQL pour créer la tâche SQL Server Agent. L'exemple suivant utilise T-SQL.
```
USE [msdb]
GO
DECLARE @jobId BINARY(16)
EXEC msdb.dbo.sp_add_job @job_name=N'MYSSISJob',
@enabled=1,
@notify_level_eventlog=0,
@notify_level_email=2,
@notify_level_page=2,
@delete_level=0,
@category_name=N'[Uncategorized (Local)]',
@job_id = @jobId OUTPUT
GO
EXEC msdb.dbo.sp_add_jobserver @job_name=N'MYSSISJob',@server_name=N'(local)'
GO
EXEC msdb.dbo.sp_add_jobstep @job_name=N'MYSSISJob',@step_name=N'ExecuteSSISPackage',
@step_id=1,
@cmdexec_success_code=0,
@on_success_action=1,
@on_fail_action=2,
@retry_attempts=0,
@retry_interval=0,
@os_run_priority=0,
@subsystem=N'SSIS',
@command=N'/ISSERVER "\"\SSISDB\MySSISFolder\MySSISProject\MySSISPackage.dtsx\"" /SERVER "\"my-rds-ssis-instance.corp-ad.company.com/\""
/Par "\"$ServerOption::LOGGING_LEVEL(Int16)\"";1 /Par "\"$ServerOption::SYNCHRONIZED(Boolean)\"";True /CALLERINFO SQLAGENT /REPORTING E',
@database_name=N'master',
@flags=0,
@proxy_name=N'SSIS_Proxy'
GO
```
## Révocation de l'accès SSIS à partir du proxy
Vous pouvez révoquer l'accès au sous-système SSIS et supprimer le proxy SSIS à l'aide des procédures stockées suivantes.
**Pour révoquer l'accès et supprimer le proxy**
1. Révoquez l'accès au sous-système.
```
USE [msdb]
GO
EXEC msdb.dbo.rds_sqlagent_proxy @task_type='REVOKE_SUBSYSTEM_ACCESS',@proxy_name='SSIS_Proxy',@proxy_subsystem='SSIS'
GO
```
1. Révoquez les octrois sur le proxy.
```
USE [msdb]
GO
EXEC msdb.dbo.sp_revoke_login_from_proxy @proxy_name=N'SSIS_Proxy',@name=N'mydomain\user_name'
GO
```
1. Supprimez le proxy.
```
USE [msdb]
GO
EXEC dbo.sp_delete_proxy @proxy_name = N'SSIS_Proxy'
GO
```