Pernyataan PL/PGSQL yang didukung

JIKA... KEMUDIAN

IF boolean-expression THEN
  statements
END IF;

Bagian berikut menunjukkan satu contoh.

IF v_user_id <> 0 THEN
  UPDATE users SET email = v_email WHERE user_id = v_user_id;
END IF;               

JIKA... LALU... LAIN

IF boolean-expression THEN
  statements
ELSE
  statements
END IF;

Bagian berikut menunjukkan satu contoh.

IF parentid IS NULL OR parentid = ''
THEN
  return_name = fullname;
  RETURN;
ELSE
  return_name = hp_true_filename(parentid) || '/' || fullname;
  RETURN;
END IF;           

JIKA... LALU... ELSIF... LALU... LAIN

Kata kunci ELSIF juga bisa dieja ELSEIF.

IF boolean-expression THEN
  statements
[ ELSIF boolean-expression THEN
  statements
[ ELSIF boolean-expression THEN
  statements
    ...] ]
[ ELSE
  statements ]
END IF;

Bagian berikut menunjukkan satu contoh.

IF number = 0 THEN
  result := 'zero';
ELSIF number > 0 THEN
  result := 'positive';
ELSIF number < 0 THEN
  result := 'negative';
ELSE
  -- the only other possibility is that number is null
  result := 'NULL';
END IF;                  

KASUS Sederhana

CASE search-expression
WHEN expression [, expression [ ... ]] THEN
  statements
[ WHEN expression [, expression [ ... ]] THEN
  statements
  ... ]
[ ELSE
  statements ]
END CASE;

Sebuah pernyataan CASE sederhana memberikan eksekusi bersyarat berdasarkan kesetaraan operan.

Nilai ekspresi pencarian dievaluasi satu kali dan berturut-turut dibandingkan dengan setiap ekspresi dalam klausa WHEN. Jika kecocokan ditemukan, maka pernyataan yang sesuai berjalan, dan kemudian kontrol diteruskan ke pernyataan berikutnya setelah END CASE. Ekspresi WHEN selanjutnya tidak dievaluasi. Jika tidak ada kecocokan yang ditemukan, pernyataan ELSE berjalan. Namun, jika ELSE tidak ada, maka pengecualian CASE_NOT_FOUND dimunculkan.

Bagian berikut menunjukkan satu contoh.

CASE x
WHEN 1, 2 THEN
  msg := 'one or two';
ELSE
  msg := 'other value than one or two';
END CASE;                  

Dicari KASUS

CASE
WHEN boolean-expression THEN
  statements
[ WHEN boolean-expression THEN
  statements
  ... ]
[ ELSE
  statements ]
END CASE;

Bentuk CASE yang dicari menyediakan eksekusi bersyarat berdasarkan kebenaran ekspresi Boolean.

Setiap ekspresi boolean klausa WHEN dievaluasi secara bergantian, sampai ditemukan yang menghasilkan true. Kemudian pernyataan yang sesuai berjalan, dan kemudian kontrol lolos ke pernyataan berikutnya setelah END CASE. Ekspresi WHEN selanjutnya tidak dievaluasi. Jika tidak ada hasil yang benar ditemukan, pernyataan ELSE dijalankan. Namun, jika ELSE tidak ada, maka pengecualian CASE_NOT_FOUND dimunculkan.

Bagian berikut menunjukkan satu contoh.

CASE
WHEN x BETWEEN 0 AND 10 THEN
  msg := 'value is between zero and ten';
WHEN x BETWEEN 11 AND 20 THEN
  msg := 'value is between eleven and twenty';
END CASE;                                

Loop sederhana

[<<label>>]
LOOP
  statements
END LOOP [ label ];

Loop sederhana mendefinisikan loop tanpa syarat yang diulang tanpa batas hingga diakhiri oleh pernyataan EXIT atau RETURN. Label opsional dapat digunakan oleh pernyataan EXIT dan CONTINUE dalam loop bersarang untuk menentukan loop mana yang dirujuk oleh pernyataan EXIT dan CONTINUE.

Bagian berikut menunjukkan satu contoh.

CREATE OR REPLACE PROCEDURE simple_loop()
LANGUAGE plpgsql
AS $$
BEGIN
  <<simple_while>>
  LOOP
    RAISE INFO 'I am raised once';  
    EXIT simple_while;
    RAISE INFO 'I am not raised';
  END LOOP;
  RAISE INFO 'I am raised once as well';
END;
$$;                

Keluar dari loop

EXIT [ label ] [ WHEN expression ];

Jika label tidak ada, loop terdalam dihentikan dan pernyataan berikut END LOOP berjalan berikutnya. Jika ada label, itu harus berupa label arus atau tingkat luar loop atau blok bersarang. Kemudian, loop atau blok bernama dihentikan dan kontrol berlanjut dengan pernyataan setelah loop atau blok END yang sesuai.

Jika WHEN ditentukan, loop exit hanya terjadi jika ekspresi benar. Jika tidak, kontrol lolos ke pernyataan setelah EXIT.

Anda dapat menggunakan EXIT dengan semua jenis loop; itu tidak terbatas untuk digunakan dengan loop tanpa syarat.

Ketika digunakan dengan blok BEGIN, EXIT meneruskan kontrol ke pernyataan berikutnya setelah akhir blok. Label harus digunakan untuk tujuan ini. EXIT yang tidak berlabel tidak pernah dianggap cocok dengan blok BEGIN.

Bagian berikut menunjukkan satu contoh.

CREATE OR REPLACE PROCEDURE simple_loop_when(x int)
LANGUAGE plpgsql
AS $$
DECLARE i INTEGER := 0;
BEGIN
  <<simple_loop_when>>
  LOOP
    RAISE INFO 'i %', i;
    i := i + 1;
    EXIT simple_loop_when WHEN (i >= x);
  END LOOP;
END;
$$;                     

Lanjutkan loop

CONTINUE [ label ] [ WHEN expression ];

Jika label tidak diberikan, eksekusi melompat ke iterasi berikutnya dari loop terdalam. Artinya, semua pernyataan yang tersisa di badan loop dilewati. Kontrol kemudian kembali ke ekspresi kontrol loop (jika ada) untuk menentukan apakah iterasi loop lain diperlukan. Jika label hadir, itu menentukan label loop yang eksekusi dilanjutkan.

Jika WHEN ditentukan, iterasi loop berikutnya dimulai hanya jika ekspresi benar. Jika tidak, kontrol lolos ke pernyataan setelah LANJUTKAN.

Anda dapat menggunakan CONTINUE dengan semua jenis loop; itu tidak terbatas untuk digunakan dengan loop tanpa syarat.

CONTINUE mylabel;

LINGKARAN SEMENTARA

[<<label>>]
WHILE expression LOOP
  statements
END LOOP [ label ];

Pernyataan WHILE mengulangi urutan pernyataan selama ekspresi boolean mengevaluasi ke true. Ekspresi diperiksa tepat sebelum setiap entri ke badan loop.

Bagian berikut menunjukkan satu contoh.

WHILE amount_owed > 0 AND gift_certificate_balance > 0 LOOP
  -- some computations here
END LOOP;

WHILE NOT done LOOP
  -- some computations here
END LOOP;                  

UNTUK loop (varian integer)

[<<label>>]
FOR name IN [ REVERSE ] expression .. expression LOOP
  statements
END LOOP [ label ];

Loop FOR (varian integer) menciptakan loop yang iterasi pada rentang nilai integer. Nama variabel secara otomatis didefinisikan sebagai tipe integer dan hanya ada di dalam loop. Setiap definisi yang ada dari nama variabel diabaikan dalam loop. Dua ekspresi yang memberikan batas bawah dan atas rentang dievaluasi satu kali saat memasuki loop. Jika Anda menentukan REVERSE, maka nilai langkah dikurangi, bukan ditambahkan, setelah setiap iterasi.

Jika batas bawah lebih besar dari batas atas (atau kurang dari, dalam kasus REVERSE), badan loop tidak berjalan. Tidak ada kesalahan yang muncul.

Jika label dilampirkan ke loop FOR, maka Anda dapat mereferensikan variabel loop integer dengan nama yang memenuhi syarat, menggunakan label itu.

Bagian berikut menunjukkan satu contoh.

FOR i IN 1..10 LOOP
  -- i will take on the values 1,2,3,4,5,6,7,8,9,10 within the loop
END LOOP;

FOR i IN REVERSE 10..1 LOOP
  -- i will take on the values 10,9,8,7,6,5,4,3,2,1 within the loop
END LOOP;                

UNTUK loop (varian set hasil)

[<<label>>]
FOR target IN query LOOP
  statements
END LOOP [ label ];

Targetnya adalah variabel rekaman atau daftar variabel skalar yang dipisahkan koma. Target secara berturut-turut ditetapkan setiap baris yang dihasilkan dari kueri, dan badan loop dijalankan untuk setiap baris.

Loop FOR (varian set hasil) memungkinkan prosedur tersimpan untuk mengulangi hasil kueri dan memanipulasi data yang sesuai.

Bagian berikut menunjukkan satu contoh.

CREATE PROCEDURE cs_refresh_reports() AS $$
DECLARE
  reports RECORD;
BEGIN
  FOR reports IN SELECT * FROM cs_reports ORDER BY sort_key LOOP
    -- Now "reports" has one record from cs_reports
    EXECUTE 'INSERT INTO ' || quote_ident(reports.report_name) || ' ' || reports.report_query;
  END LOOP;
  RETURN;
END;
$$ LANGUAGE plpgsql;                   

UNTUK loop dengan SQL dinamis

[<<label>>]
FOR record_or_row IN EXECUTE text_expression LOOP 
  statements
END LOOP;

Sebuah FOR loop dengan SQL dinamis memungkinkan prosedur tersimpan untuk iterasi melalui hasil query dinamis dan memanipulasi data yang sesuai.

Bagian berikut menunjukkan satu contoh.

CREATE OR REPLACE PROCEDURE for_loop_dynamic_sql(x int)
LANGUAGE plpgsql
AS $$
DECLARE
  rec RECORD;
  query text;
BEGIN
  query := 'SELECT * FROM tbl_dynamic_sql LIMIT ' || x;
  FOR rec IN EXECUTE query
  LOOP
    RAISE INFO 'a %', rec.a;
  END LOOP;
END;
$$;

Buka untuk pilih: Variabel kursor dibuka dan diberikan kueri yang ditentukan untuk dijalankan. Kursor belum bisa dibuka. Juga, itu pasti telah dideklarasikan sebagai kursor tidak terikat (yaitu, sebagai refcursor variabel sederhana). Kueri SELECT diperlakukan dengan cara yang sama seperti pernyataan SELECT lainnya di PL/PGSQL.

OPEN cursor_name FOR SELECT ...;                     

Bagian berikut menunjukkan satu contoh.

OPEN curs1 FOR SELECT * FROM foo WHERE key = mykey;    

Buka untuk dieksekusi: Variabel kursor dibuka dan diberikan kueri yang ditentukan untuk dijalankan. Kursor belum bisa dibuka. Juga, itu pasti telah dideklarasikan sebagai kursor tidak terikat (yaitu, sebagai refcursor variabel sederhana). Query ditentukan sebagai ekspresi string dengan cara yang sama seperti pada perintah EXECUTE. Pendekatan ini memberikan fleksibilitas sehingga kueri dapat bervariasi dari satu run ke yang berikutnya.

OPEN cursor_name FOR EXECUTE query_string;

Bagian berikut menunjukkan satu contoh.

OPEN curs1 FOR EXECUTE 'SELECT * FROM ' || quote_ident($1);

Buka kursor terikat: Bentuk OPEN ini digunakan untuk membuka variabel kursor yang kuerinya terikat padanya ketika dideklarasikan. Kursor belum bisa dibuka. Daftar ekspresi nilai argumen aktual harus muncul jika dan hanya jika kursor dideklarasikan untuk mengambil argumen. Nilai-nilai ini diganti dalam kueri.

OPEN bound_cursor_name [ ( argument_values ) ];

Bagian berikut menunjukkan satu contoh.

OPEN curs2;
OPEN curs3(42);

FETCH mengambil baris berikutnya dari kursor ke target. Target ini dapat berupa variabel baris, variabel rekaman, atau daftar variabel sederhana yang dipisahkan koma, seperti halnya SELECT INTO. Seperti halnya SELECT INTO, Anda dapat memeriksa variabel khusus FOUND untuk melihat apakah baris diperoleh.

FETCH cursor INTO target;

Bagian berikut menunjukkan satu contoh.

FETCH curs1 INTO rowvar;

CLOSE menutup portal yang mendasari kursor terbuka. Anda dapat menggunakan pernyataan ini untuk melepaskan sumber daya lebih awal dari akhir transaksi. Anda juga dapat menggunakan pernyataan ini untuk membebaskan variabel kursor untuk dibuka lagi.

CLOSE cursor;

Bagian berikut menunjukkan satu contoh.

CLOSE curs1;