AWS SDK for Java 1.x は 2025 年 12 月 31 日にend-of-supportしました。新しい機能、可用性の向上、セキュリティ更新のために、[AWS SDK for Java 2.x](https://docs.aws.amazon.com/sdk-for-java/latest/developer-guide/home.html) に移行することをお勧めします。

翻訳は機械翻訳により提供されています。提供された翻訳内容と英語版の間で齟齬、不一致または矛盾がある場合、英語版が優先します。

# Gradle とともに SDK を使用する
<a name="setup-project-gradle"></a>

[Gradle](https://gradle.com/) プロジェクトの SDK 依存関係を管理するには、 の Maven BOM AWS SDK for Java をアプリケーションの `build.gradle` ファイルにインポートします。

**注記**  
次の例では、構築ファイルの *1.12.529* を有効なバージョンの AWS SDK for Javaに置き換えます。[Maven Central リポジトリ](https://mvnrepository.com/artifact/com.amazonaws/aws-java-sdk-bom/latest)で最新バージョンを検索してください。

## Gradle 4.6 以降のプロジェクト設定
<a name="project-setup-for-gradle-4-6-or-higher"></a>

 [Gradle 4.6 以降](https://docs.gradle.org/4.6/release-notes.html#bom-import)、BOM で依存関係を宣言することにより、Gradle の改善された POM サポート機能を使用して部品表 (BOM) ファイルをインポートできます。

1. Gradle 5.0 以降を使用している場合は、ステップ 2 に進みます。それ以外の場合は、`settings.gradle` ファイルで *IMPROVED\$1POM\$1SUPPORT* 機能を有効にします。

   ```
   enableFeaturePreview('IMPROVED_POM_SUPPORT')
   ```

1. アプリケーションの `build.gradle` ファイルの *dependencies* セクションに BOM を追加します。

   ```
   ...
   dependencies {
       implementation platform('com.amazonaws:aws-java-sdk-bom:1.12.529')
   
       // Declare individual SDK dependencies without version
       ...
   }
   ```

1. *dependencies* セクションで使用する SDK モジュールを指定します。たとえば、以下には Amazon Simple Storage Service () の依存関係が含まれますAmazon S3。

   ```
   ...
   dependencies {
       implementation platform('com.amazonaws:aws-java-sdk-bom:1.12.529')
       implementation 'com.amazonaws:aws-java-sdk-s3'
       ...
   }
   ```

Gradle は BOM の情報を使用して、正しいバージョンの SDK 依存関係を自動的に解決します。

以下は、 の依存関係を含む完全な`build.gradle`ファイルの例です Amazon S3。

```
group 'aws.test'
version '1.0-SNAPSHOT'

apply plugin: 'java'

sourceCompatibility = 1.8

repositories {
  mavenCentral()
}

dependencies {
  implementation platform('com.amazonaws:aws-java-sdk-bom:1.12.529')
  implementation 'com.amazonaws:aws-java-sdk-s3'
}
```

**注記**  
前の例では、 の依存関係を Amazon S3 、プロジェクトで使用する AWS サービスの依存関係に置き換えます。BOM によって管理されるモジュール (依存関係) AWS SDK for Java は [Maven 中央リポジトリ](https://mvnrepository.com/artifact/com.amazonaws/aws-java-sdk-bom/latest)に一覧表示されます。

## 4.6 より前の Gradle バージョンのプロジェクト設定
<a name="project-setup-for-gradle-versions-earlier-than-4-6"></a>

4.6 より前の Gradle バージョンでは、ネイティブ BOM がサポートされていません。プロジェクトの AWS SDK for Java 依存関係を管理するには、Spring の Gradle 用[依存関係管理プラグイン](https://github.com/spring-gradle-plugins/dependency-management-plugin)を使用して SDK の Maven BOM をインポートします。

1. ご自身のアプリケーションの `build.gradle` ファイルに依存関係管理プラグインを追加します。

   ```
   buildscript {
       repositories {
           mavenCentral()
       }
       dependencies {
           classpath "io.spring.gradle:dependency-management-plugin:1.0.9.RELEASE"
       }
   }
   
   apply plugin: "io.spring.dependency-management"
   ```

1. ファイルの *dependencyManagement* セクションに BOM を追加します。

   ```
   dependencyManagement {
       imports {
           mavenBom 'com.amazonaws:aws-java-sdk-bom:1.12.529'
       }
   }
   ```

1. *dependencies* セクションで使用する SDK モジュールを指定します。たとえば次の例には、 Amazon S3の依存関係が含まれています。

   ```
   dependencies {
       compile 'com.amazonaws:aws-java-sdk-s3'
   }
   ```

Gradle は BOM の情報を使用して、正しいバージョンの SDK 依存関係を自動的に解決します。

以下は、 の依存関係を含む完全な`build.gradle`ファイルの例です Amazon S3。

```
group 'aws.test'
version '1.0'

apply plugin: 'java'

sourceCompatibility = 1.8

repositories {
  mavenCentral()
}

buildscript {
  repositories {
    mavenCentral()
  }
  dependencies {
    classpath "io.spring.gradle:dependency-management-plugin:1.0.9.RELEASE"
  }
}

apply plugin: "io.spring.dependency-management"

dependencyManagement {
  imports {
    mavenBom 'com.amazonaws:aws-java-sdk-bom:1.12.529'
  }
}

dependencies {
  compile 'com.amazonaws:aws-java-sdk-s3'
  testCompile group: 'junit', name: 'junit', version: '4.11'
}
```

**注記**  
前の例では、 の依存関係を Amazon S3 、プロジェクトで使用する AWS サービスの依存関係に置き換えます。BOM によって管理されるモジュール (依存関係) AWS SDK for Java は [Maven 中央リポジトリ](https://mvnrepository.com/artifact/com.amazonaws/aws-java-sdk-bom/latest)に一覧表示されます。

BOM を使用した SDK の依存関係の指定の詳細については、[Apache Maven とともに SDK を使用する](setup-project-maven.md)を参照してください。