Usar o CloudWatch Logs Insights para explorar medições do Monitor de Internet

Você pode usar as consultas do CloudWatch Logs Insights para filtrar um subconjunto de logs para uma cidade ou área geográfica específica (localização do cliente), ASN (ISP) do cliente e localização de origem da AWS. O Monitor de Internet do Amazon CloudWatch publica medições granulares de disponibilidade e tempo de ida e volta para o CloudWatch Logs, que você pode explorar usando o CloudWatch Logs Insights.

Para saber mais sobre a precisão da localização do cliente no Monitor de Internet, consulte Informações e precisão de geolocalização no Monitor de Internet.

Os exemplos nesta seção podem ajudar a criar consultas do CloudWatch Logs Insights para saber mais sobre suas próprias medidas e métricas de tráfego de aplicações. Se você usar esses exemplos no CloudWatch Logs Insights, substitua monitorName pelo seu próprio nome de monitor.

Ver sugestões para otimização de tráfego

Na guia Insights de tráfego, no Monitor de Internet, é possível ver sugestões de otimização de tráfego, filtradas por um local. Para ver as mesmas informações exibidas na seção Sugestões de otimização de tráfego nessa guia, mas sem o filtro de granularidade de localização, é possível usar a consulta a seguir do CloudWatch Logs Insights.

fields @timestamp, 
clientLocation.city as @city, clientLocation.subdivision as @subdivision, clientLocation.country as @country,
`trafficInsights.timeToFirstByte.currentExperience.serviceName` as @serviceNameField,
concat(@serviceNameField, ` (`, `serviceLocation`, `)`) as @currentExperienceField,
concat(`trafficInsights.timeToFirstByte.ec2.serviceName`, ` (`, `trafficInsights.timeToFirstByte.ec2.serviceLocation`, `)`) as @ec2Field,
`trafficInsights.timeToFirstByte.cloudfront.serviceName` as @cloudfrontField,
concat(`clientLocation.networkName`, ` (AS`, `clientLocation.asn`, `)`) as @networkName
| filter ispresent(`trafficInsights.timeToFirstByte.currentExperience.value`)
| stats avg(`trafficInsights.timeToFirstByte.currentExperience.value`) as @averageTTFB,
avg(`trafficInsights.timeToFirstByte.ec2.value`) as @ec2TTFB,
avg(`trafficInsights.timeToFirstByte.cloudfront.value`) as @cloudfrontTTFB,
sum(`bytesIn` + `bytesOut`) as @totalBytes,
latest(@ec2Field) as @ec2,
latest(@currentExperienceField) as @currentExperience,
latest(@cloudfrontField) as @cloudfront,
count(*) by @networkName, @city, @subdivision, @country
| display @city, @subdivision, @country, @networkName, @totalBytes, @currentExperience, @averageTTFB, @ec2, @ec2TTFB, @cloudfront, @cloudfrontTTFB
| sort @totalBytes desc

Ver a disponibilidade da Internet e o RTT (p50, p90 e p95)

Para ver a disponibilidade da Internet e o tempo de ida e volta (p50, p90 e p95) do tráfego, é possível usar a consulta a seguir do CloudWatch Logs Insights.

Área geográfica do usuário final: Chicago, IL, Estados Unidos

Rede de usuário final (ASN): AS7018

Local do serviço da AWS: Região Leste dos EUA (N. da Virgínia)

Para obter os logs, faça o seguinte:

A consulta retorna todos os dados de performance dos usuários conectados a partir de AS7018 em Chicago, IL, seguindo em direção à região Leste dos EUA (Norte da Virgínia) durante o período selecionado.

fields @timestamp, 
internetHealth.availability.experienceScore as availabilityExperienceScore, 
internetHealth.availability.percentageOfTotalTrafficImpacted as percentageOfTotalTrafficImpacted,
internetHealth.performance.experienceScore as performanceExperienceScore,
internetHealth.performance.roundTripTime.p50 as roundTripTimep50, 
internetHealth.performance.roundTripTime.p90 as roundTripTimep90, 
internetHealth.performance.roundTripTime.p95 as roundTripTimep95
 | filter clientLocation.country == `United States` 
 and clientLocation.city == `Chicago` 
 and serviceLocation == `us-east-1` 
 and clientLocation.asn == 7018

Para obter mais informações, consulte Analisar logs de dados com o CloudWatch Logs Insights.