Criar e gerenciar recursos de alertas usando o Terraform

Crie uma nova conta de serviço para o pipeline de CI.

Atribua o perfil “Acessar as regras de alerta da API de provisionamento”.

Criar um token de conta de serviço.

Nomeie e salve o token para uso no Terraform.

Copie esse bloco de código em um arquivo .tf na máquina local. Substitua <slack-webhook-url> pelo URL do webhook do Slack (ou outro contato)

Este exemplo cria um ponto de contato que envia notificações de alerta para o Slack.

resource "grafana_contact_point" "my_slack_contact_point" {
    name = "Send to My Slack Channel"

    slack {
        url = <slack-webhook-url>
        text = <<EOT
{{ len .Alerts.Firing }} alerts are firing!

Alert summaries:
{{ range .Alerts.Firing }}
{{ template "Alert Instance Template" . }}
{{ end }}
EOT
    }
}

Insira texto para a notificação no campo de texto.

O campo text é compatível com modelos no estilo Go. Isso possibilita que você gerencie os modelos de notificação do Grafana Alerting diretamente no Terraform.

Execute o comando terraform apply.

Acesse a interface de usuário do Grafana e verifique os detalhes do ponto de contato.

Você não pode editar os recursos provisionados via Terraform na interface de usuário. Isso garante que a pilha de alertas esteja sempre sincronizada com o código.

Clique em Testar para verificar se o ponto de contato funciona corretamente.

Copie esse bloco de código em um arquivo .tf na máquina local.

Neste exemplo, os alertas são agrupados por alertname, o que significa que todas as notificações provenientes de alertas que compartilham o mesmo nome são agrupadas na mesma mensagem do Slack.

Se quiser rotear notificações específicas de forma diferente, você pode adicionar subpolíticas. As subpolíticas permitem que você aplique o roteamento a diferentes alertas com base na correspondência de rótulos. Neste exemplo, aplicamos um tempo de desativação de áudio a todos os alertas com o rótulo a=b.

resource "grafana_notification_policy" "my_policy" {
    group_by = ["alertname"]
    contact_point = grafana_contact_point.my_slack_contact_point.name

    group_wait = "45s"
    group_interval = "6m"
    repeat_interval = "3h"

    policy {
        matcher {
            label = "a"
            match = "="
            value = "b"
        }
        group_by = ["..."]
        contact_point = grafana_contact_point.a_different_contact_point.name
        mute_timings = [grafana_mute_timing.my_mute_timing.name]

        policy {
            matcher {
                label = "sublabel"
                match = "="
                value = "subvalue"
            }
            contact_point = grafana_contact_point.a_third_contact_point.name
            group_by = ["..."]
        }
    }
}

No campo mute_timings, vincule um tempo de desativação de áudio à política de notificação.

Execute o comando terraform apply.

Acesse a interface de usuário do Grafana e verifique os detalhes da política de notificação.

Clique em Testar para verificar se o ponto de notificação está funcionando corretamente.

Copie esse bloco de código em um arquivo .tf na máquina local.

Neste exemplo, as notificações de alerta têm o áudio desativado nos finais de semana.

resource "grafana_mute_timing" "my_mute_timing" {
    name = "My Mute Timing"

    intervals {
        times {
          start = "04:56"
          end = "14:17"
        }
        weekdays = ["saturday", "sunday", "tuesday:thursday"]
        months = ["january:march", "12"]
        years = ["2025:2027"]
    }
}

Execute o comando terraform apply.

Acesse a interface de usuário do Grafana e verifique os detalhes do tempo de desativação de áudio.

Referencie o tempo de desativação de áudio recém-criado em uma política de notificação usando o campo mute_timings. Isso aplicará seu tempo de desativação de áudio a algumas ou a todas as notificações.

Clique em Testar para verificar se o tempo de desativação de áudio está funcionando corretamente.

Crie uma fonte de dados para consultar e uma pasta para armazenar as regras.

Neste exemplo, a fonte de dados Configurar uma fonte de TestData dados para testes é usada.

Os alertas podem ser definidos em relação a qualquer fonte de dados de backend no Grafana.

resource "grafana_data_source" "testdata_datasource" {
    name = "TestData"
    type = "testdata"
}

resource "grafana_folder" "rule_folder" {
    title = "My Rule Folder"
}

Defina uma regra de alerta.

Para obter mais informações sobre as regras de alerta, consulte How to create Grafana-managed alerts.

Crie um grupo de regras contendo uma ou mais regras.

Neste exemplo, o grupo de recursos grafana_rule_group é usado.

resource "grafana_rule_group" "my_rule_group" {
    name = "My Alert Rules"
    folder_uid = grafana_folder.rule_folder.uid
    interval_seconds = 60
    org_id = 1

    rule {
        name = "My Random Walk Alert"
        condition = "C"
        for = "0s"

        // Query the datasource.
        data {
            ref_id = "A"
            relative_time_range {
                from = 600
                to = 0
            }
            datasource_uid = grafana_data_source.testdata_datasource.uid
            // `model` is a JSON blob that sends datasource-specific data.
            // It's different for every datasource. The alert's query is defined here.
            model = jsonencode({
                intervalMs = 1000
                maxDataPoints = 43200
                refId = "A"
            })
        }

        // The query was configured to obtain data from the last 60 seconds. Let's alert on the average value of that series using a Reduce stage.
        data {
            datasource_uid = "__expr__"
            // You can also create a rule in the UI, then GET that rule to obtain the JSON.
            // This can be helpful when using more complex reduce expressions.
            model = <<EOT
{"conditions":[{"evaluator":{"params":[0,0],"type":"gt"},"operator":{"type":"and"},"query":{"params":["A"]},"reducer":{"params":[],"type":"last"},"type":"avg"}],"datasource":{"name":"Expression","type":"__expr__","uid":"__expr__"},"expression":"A","hide":false,"intervalMs":1000,"maxDataPoints":43200,"reducer":"last","refId":"B","type":"reduce"}
EOT
            ref_id = "B"
            relative_time_range {
                from = 0
                to = 0
            }
        }

        // Now, let's use a math expression as our threshold.
        // We want to alert when the value of stage "B" above exceeds 70.
        data {
            datasource_uid = "__expr__"
            ref_id = "C"
            relative_time_range {
                from = 0
                to = 0
            }
            model = jsonencode({
                expression = "$B > 70"
                type = "math"
                refId = "C"
            })
        }
    }
}

Acesse a interface de usuário do Grafana e verifique a regra de alerta.

Você pode ver se a regra de alerta está disparando. Você também pode verificar uma visualização de cada um dos estágios de consulta da regra de alerta.

Quando o alerta é disparado, o Grafana roteia uma notificação por meio da política que você definiu.

Por exemplo, se você escolheu o Slack como ponto de contato, o Alertmanager incorporado do Grafana publica automaticamente uma mensagem no Slack.