As traduções são geradas por tradução automática. Em caso de conflito entre o conteúdo da tradução e da versão original em inglês, a versão em inglês prevalecerá.

DDLdeclarações (linguagem de definição de dados) no Amazon Keyspaces

A linguagem de definição de dados (DDL) é o conjunto de instruções da Cassandra Query Language (CQL) que você usa para gerenciar estruturas de dados no Amazon Keyspaces (para Apache Cassandra), como keyspaces e tabelas. Você usa DDL para criar essas estruturas de dados, modificá-las depois de criadas e removê-las quando não estiverem mais em uso. O Amazon Keyspaces executa DDL operações de forma assíncrona. Para obter mais informações sobre como confirmar se uma operação assíncrona foi concluída, consulte Criação e exclusão assíncronas de espaços de chave e tabelas.

As seguintes DDL declarações são apoiadas:

Keyspaces

Um espaço de chaves agrupa tabelas relacionadas que são relevantes para um ou mais aplicativos. Em termos de um sistema de gerenciamento de banco de dados relacional (RDBMS), os espaços-chave são aproximadamente semelhantes aos bancos de dados, espaços de tabela ou construções similares.

Para informações sobre limites e restrições de cota para os espaços de chaves do Amazon Keyspaces, consulte Cotas para Amazon Keyspaces (para Apache Cassandra).

CREATE KEYSPACE

Use a instrução CREATE KEYSPACE para criar um novo espaço de chaves.

Sintaxe

create_keyspace_statement ::= 
    CREATE KEYSPACE [ IF NOT EXISTS ] keyspace_name
    WITH options

Em que:

Exemplo

Crie um espaço de chaves da seguinte forma.

CREATE KEYSPACE my_keyspace
    WITH REPLICATION = {'class': 'SingleRegionStrategy'} and TAGS ={'key1':'val1', 'key2':'val2'} ;

Para criar um espaço de chave multirregional, especifique NetworkTopologyStrategy e inclua pelo menos dois e até seis Regiões da AWS. O fator de replicação para cada região é três.

CREATE KEYSPACE my_keyspace
    WITH REPLICATION = {'class':'NetworkTopologyStrategy', 'us-east-1':'3', 'ap-southeast-1':'3','eu-west-1':'3'};

ALTER KEYSPACE

Você pode usar ALTER KEYSPACE para adicionar ou remover tags de um keyspace.

Para adicionar ou remover tags, você pode usar a sintaxe a seguir.

Sintaxe

alter_keyspace_statement ::= 
    ALTER KEYSPACE keyspace_name
    [[ADD | DROP] TAGS

Em que:

Exemplo

Altere um espaço de chaves da seguinte forma.

ALTER KEYSPACE my_keyspace ADD TAGS {'key1':'val1', 'key2':'val2'};

DROP KEYSPACE

Use a instrução DROP KEYSPACE para remover um espaço de chaves, incluindo todo o seu conteúdo, como tabelas.

Sintaxe

drop_keyspace_statement ::= 
    DROP KEYSPACE [ IF EXISTS ] keyspace_name

Em que:

Exemplo

DROP KEYSPACE "myGSGKeyspace";

Tabelas

As tabelas são as principais estruturas de dados no Amazon Keyspaces. Os dados em uma tabela são organizados em linhas e colunas. Um subconjunto dessas colunas é usado para determinar o particionamento (e, em última análise, o posicionamento dos dados) por meio da especificação de uma chave de partição.

Outro conjunto de colunas pode ser definido em colunas de cluster, o que significa que elas podem participar como predicados na execução da consulta.

Por padrão, novas tabelas são criadas com capacidade de throughput sob demanda. Você pode alterar o modo de capacidade de tabelas novas e existentes. Para obter mais informações sobre os modos de throughput da capacidade de leitura/gravação, consulte Configure os modos de capacidade de leitura/gravação no Amazon Keyspaces.

Para tabelas no modo provisionado, você pode configurar opcionais. AUTOSCALING_SETTINGS Para obter mais informações sobre o auto scaling do Amazon Keyspaces e as opções disponíveis, consulte. Configurar o escalonamento automático em uma tabela existente

Para informações sobre limites e restrições de cotas para tabelas do Amazon Keyspaces, consulte Cotas para Amazon Keyspaces (para Apache Cassandra).

CREATE TABLE

Use a instrução do CREATE TABLE para criar uma nova tabela.

Sintaxe

create_table_statement ::=  CREATE TABLE [ IF NOT EXISTS ] table_name
    '('
        column_definition 
        ( ',' column_definition )*
        [ ',' PRIMARY KEY '(' primary_key ')' ]
    ')' [ WITH table_options ]

column_definition      ::=  column_name cql_type [ FROZEN ][ STATIC ][ PRIMARY KEY]

primary_key            ::=  partition_key [ ',' clustering_columns ]

partition_key          ::=  column_name
                              | '(' column_name ( ',' column_name )* ')'

clustering_columns     ::=  column_name ( ',' column_name )*

table_options          ::=  [table_options]
                              | CLUSTERING ORDER BY '(' clustering_order ')' [ AND table_options ]
                              | options
                              | CUSTOM_PROPERTIES
                              | AUTOSCALING_SETTINGS
                              | default_time_to_live
                              | TAGS

clustering_order       ::=  column_name (ASC | DESC) ( ',' column_name (ASC | DESC) )*

Em que:

Exemplo

CREATE TABLE IF NOT EXISTS "my_keyspace".my_table (
                                            id text,
                                            name text,
                                            region text,
                                            division text,
                                            project text,
                                            role text,
                                            pay_scale int,
                                            vacation_hrs float,
                                            manager_id text,
                                            PRIMARY KEY (id,division))
                                            WITH CUSTOM_PROPERTIES={
                                                'capacity_mode':{
                                                        'throughput_mode': 'PROVISIONED', 'read_capacity_units': 10, 'write_capacity_units': 20
                                                    },
                                                'point_in_time_recovery':{'status': 'enabled'},
                                                'encryption_specification':{
                                                        'encryption_type': 'CUSTOMER_MANAGED_KMS_KEY', 
                                                        'kms_key_identifier':'arn:aws:kms:eu-west-1:5555555555555:key/11111111-1111-111-1111-111111111111'
                                                    }
                                            }
                                            AND CLUSTERING ORDER BY (division ASC) 
                                            AND TAGS={'key1':'val1', 'key2':'val2'}
                                            AND default_time_to_live = 3024000;

Em uma tabela que usa colunas de cluster, as colunas sem cluster podem ser declaradas como estáticas na definição da tabela. Para obter mais informações sobre as colunas estáticas, consulte Estime o consumo de capacidade para colunas estáticas no Amazon Keyspaces.

Exemplo

CREATE TABLE "my_keyspace".my_table (
                                            id int,
                                            name text,
                                            region text,
                                            division text,
                                            project text STATIC,
                                            PRIMARY KEY (id,division));

ALTER TABLE

Use a instrução ALTER TABLE para adicionar novas colunas, adicionar tags ou alterar as propriedades personalizadas da tabela.

Sintaxe

alter_table_statement ::=  ALTER TABLE table_name    
 
        [ ADD ( column_definition | column_definition_list)  ] 
        [[ADD | DROP] TAGS {'key1':'val1', 'key2':'val2'}]            
        [ WITH table_options [ , ... ] ] ;
        
column_definition      ::=  column_name cql_type
                    
                

Em que:

Exemplos

A instrução a seguir mostra como adicionar uma coluna a uma tabela existente.

ALTER TABLE mykeyspace.mytable ADD (ID int);

Essa instrução mostra como adicionar duas colunas de coleção a uma tabela existente:

ALTER TABLE my_Table ADD(col_frozen_list FROZEN<LIST<FROZEN<SET<TEXT>>>>, col_map MAP<INT, FROZEN<SET<INT>>>);

Para alterar o modo de capacidade de uma tabela e especificar unidades de capacidade de leitura e gravação, você pode usar a seguinte declaração.

ALTER TABLE mykeyspace.mytable WITH CUSTOM_PROPERTIES={'capacity_mode':{'throughput_mode': 'PROVISIONED', 'read_capacity_units': 10, 'write_capacity_units': 20}};

A declaração a seguir especifica uma KMS chave gerenciada pelo cliente para a tabela.

ALTER TABLE mykeyspace.mytable WITH CUSTOM_PROPERTIES={     
              'encryption_specification':{ 
                      'encryption_type': 'CUSTOMER_MANAGED_KMS_KEY', 
                      'kms_key_identifier':'arn:aws:kms:eu-west-1:5555555555555:key/11111111-1111-111-1111-111111111111'     
                  } 
         };

Para ativar a point-in-time restauração de uma tabela, você pode usar a instrução a seguir.

ALTER TABLE mykeyspace.mytable WITH CUSTOM_PROPERTIES={'point_in_time_recovery': {'status': 'enabled'}};

Para definir um valor padrão de tempo de vida em segundos para uma tabela, você pode usar a seguinte declaração.

ALTER TABLE my_table WITH default_time_to_live = 2592000;

Essa instrução habilita configurações personalizadas de tempo de vida para uma tabela.

ALTER TABLE mytable WITH CUSTOM_PROPERTIES={'ttl':{'status': 'enabled'}};

RESTORE TABLE

Use a instrução do RESTORE TABLE ou restaure uma tabela para um ponto no tempo. Essa declaração exige que a point-in-time recuperação seja ativada em uma tabela. Para obter mais informações, consulte Faça backup e restaure dados com point-in-time recuperação para Amazon Keyspaces.

Sintaxe

restore_table_statement ::=  
    RESTORE TABLE restored_table_name FROM TABLE source_table_name 
                    [ WITH table_options [ , ... ] ];

Em que:

Exemplo

RESTORE TABLE mykeyspace.mytable_restored from table mykeyspace.my_table 
WITH restore_timestamp = '2020-06-30T04:05:00+0000'
AND custom_properties = {'point_in_time_recovery':{'status':'disabled'}, 'capacity_mode':{'throughput_mode': 'PROVISIONED', 'read_capacity_units': 10, 'write_capacity_units': 20}}
AND TAGS={'key1':'val1', 'key2':'val2'};

DROP TABLE

Use a instrução DROP TABLE para remover uma tabela do espaço de chaves.

Sintaxe

drop_table_statement ::=  
    DROP TABLE [ IF EXISTS ] table_name

Em que:

Exemplo

DROP TABLE "myGSGKeyspace".employees_tbl;